Running nixpkgs-update (https://nix-community.org/update-bot/) with UPDATE_INFO: calc 2.15.0.2 -> 2.17.0.0 https://repology.org/project/calc-arbitrary-precision-calculator/versions
attrpath: calc
Checking auto update branch...
No auto update branch exists
Old version 2.15.0.2" not present in master derivation file with contents: {
  lib,
  stdenv,
  fetchurl,
  man,
  ncurses,
  readline,
  enableReadline ? true,
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "calc";
  version = "2.17.0.0";

  src = fetchurl {
    urls = [
      "https://github.com/lcn2/calc/releases/download/v${finalAttrs.version}/calc-${finalAttrs.version}.tar.bz2"
      "http://www.isthe.com/chongo/src/calc/calc-${finalAttrs.version}.tar.bz2"
    ];
    hash = "sha256-Cso4Z8E5UBsoXCluuujZ+4Slppb5k6K+EDRPKKrqrDk=";
  };

  postPatch = ''
    substituteInPlace Makefile.target \
      --replace '-install_name ''${LIBDIR}/libcalc''${LIB_EXT_VERSION}' '-install_name ''${T}''${LIBDIR}/libcalc''${LIB_EXT_VERSION}' \
      --replace '-install_name ''${LIBDIR}/libcustcalc''${LIB_EXT_VERSION}' '-install_name ''${T}''${LIBDIR}/libcustcalc''${LIB_EXT_VERSION}'
  '';

  nativeBuildInputs = [
    man
  ];

  buildInputs = lib.optionals enableReadline [
    ncurses
    readline
  ];

  makeFlags = [
    "T=$(out)"
    "INCDIR="
    "BINDIR=/bin"
    "LIBDIR=/lib"
    "CALC_SHAREDIR=/share/calc"
    "CALC_INCDIR=/include"
    "MANDIR=/share/man/man1"

    "EXTRA_CFLAGS=-Wno-error=format-security"
    # Handle LDFLAGS defaults in calc
    "DEFAULT_LIB_INSTALL_PATH=$(out)/lib"
  ]
  ++ lib.optionals enableReadline [
    "READLINE_LIB=-lreadline"
    "USE_READLINE=-DUSE_READLINE"
  ];

  meta = {
    homepage = "http://www.isthe.com/chongo/tech/comp/calc/";
    description = "C-style arbitrary precision calculator";
    mainProgram = "calc";
    changelog = "https://github.com/lcn2/calc/blob/v${finalAttrs.version}/CHANGES";
    # The licensing situation depends on readline (see section 3 of the LGPL)
    # If linked against readline then GPLv2 otherwise LGPLv2.1
    license = if enableReadline then lib.licenses.gpl2Only else lib.licenses.lgpl21Only;
    maintainers = [ ];
    platforms = lib.platforms.all;
  };
})