Running nixpkgs-update (https://nix-community.org/update-bot/) with UPDATE_INFO: cri-o 1.36.4 -> 1.36.5 https://repology.org/project/cri-o/versions
attrpath: cri-o
Checking auto update branch...
No auto update branch exists
Old version 1.36.4" not present in master derivation file with contents: {
  lib,
  btrfs-progs,
  buildGoModule,
  fetchFromGitHub,
  glibc,
  gpgme,
  installShellFiles,
  libapparmor,
  libseccomp,
  libselinux,
  lvm2,
  pkg-config,
  nixosTests,
  go-md2man,
}:

buildGoModule (finalAttrs: {
  pname = "cri-o";
  version = "1.36.5";

  src = fetchFromGitHub {
    owner = "cri-o";
    repo = "cri-o";
    tag = "v${finalAttrs.version}";
    hash = "sha256-J6mTZw4R2gqVlv07jqS8LoEMRLGrMSP3oE79lp+yLJ0=";
  };
  vendorHash = null;

  doCheck = false;

  outputs = [
    "out"
    "man"
  ];
  nativeBuildInputs = [
    installShellFiles
    go-md2man
    pkg-config
  ];

  buildInputs = [
    btrfs-progs
    gpgme
    libapparmor
    libseccomp
    libselinux
    lvm2
  ]
  ++ lib.optionals (glibc != null) [
    glibc
    glibc.static
  ];

  env.BUILDTAGS = toString [
    "apparmor"
    "seccomp"
    "selinux"
    "containers_image_openpgp"
    "containers_image_ostree_stub"
  ];

  buildPhase = ''
    runHook preBuild
    sed -i 's;\thack/;\tbash ./hack/;g' Makefile
    make binaries docs BUILDTAGS="$BUILDTAGS"
    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall
    install -Dm755 bin/* -t $out/bin

    for shell in bash fish zsh; do
      installShellCompletion --$shell completions/$shell/*
    done

    install contrib/cni/*.conflist -Dt $out/etc/cni/net.d
    install crictl.yaml -Dt $out/etc

    installManPage docs/*.[1-9]
    runHook postInstall
  '';

  passthru.tests = { inherit (nixosTests) cri-o; };

  meta = {
    homepage = "https://cri-o.io";
    description = ''
      Open Container Initiative-based implementation of the
      Kubernetes Container Runtime Interface
    '';
    license = lib.licenses.asl20;
    teams = [ lib.teams.podman ];
    platforms = lib.platforms.linux;
  };
})