Running nixpkgs-update (https://nix-community.org/update-bot/) with UPDATE_INFO: detect-it-easy 3.10 -> 3.21 https://repology.org/project/detect-it-easy/versions
attrpath: detect-it-easy
Checking auto update branch...
No auto update branch exists
Old version 3.10" not present in master derivation file with contents: {
  lib,
  stdenv,
  fetchFromGitHub,
  libsForQt5,
  freetype,
  graphite2,
  icu,
  krb5,
  systemdLibs,
  imagemagick,
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "detect-it-easy";
  version = "3.21";

  src = fetchFromGitHub {
    owner = "horsicq";
    repo = "DIE-engine";
    tag = finalAttrs.version;
    fetchSubmodules = true;
    hash = "sha256-gst0suw5mNR3A0s/jIfte41cOOxKR0IsTFkO7ydwKMs=";
  };

  postPatch = ''
        # Convert CRLF to LF so substituteInPlace works
        tr -d '\r' < XOptions/xoptions.cpp > XOptions/xoptions.cpp.tmp
        mv XOptions/xoptions.cpp.tmp XOptions/xoptions.cpp

        substituteInPlace XOptions/xoptions.cpp \
          --replace-fail 'QString XOptions::getApplicationDataPath()
    {
        QString sResult;' 'QString XOptions::getApplicationDataPath()
    {
    #if defined(Q_OS_LINUX)
        return qApp->applicationDirPath() + "/../lib/die";
    #endif
        QString sResult;'
  '';

  buildInputs = [
    libsForQt5.qtbase
    libsForQt5.qtscript
    libsForQt5.qtsvg
    graphite2
    freetype
    icu
    krb5
    systemdLibs
  ];
  nativeBuildInputs = [
    libsForQt5.wrapQtAppsHook
    libsForQt5.qmake
    imagemagick
  ];

  enableParallelBuilding = true;

  # work around wrongly created dirs in `install.sh`
  # https://github.com/horsicq/DIE-engine/issues/110
  preInstall = ''
    mkdir -p $out/bin
    mkdir -p $out/share/applications
    mkdir -p $out/share/icons
  '';

  postInstall = ''
    cp -r $src/XYara/yara_rules $out/lib/die/
  '';

  meta = {
    description = "Program for determining types of files for Windows, Linux and MacOS";
    mainProgram = "die";
    homepage = "https://github.com/horsicq/Detect-It-Easy";
    changelog = "https://github.com/horsicq/Detect-It-Easy/blob/master/changelog.txt";
    maintainers = with lib.maintainers; [ ivyfanchiang ];
    platforms = [
      "x86_64-linux"
      "aarch64-linux"
    ];
    license = lib.licenses.mit;
  };
})