Running nixpkgs-update (https://nix-community.org/update-bot/) with UPDATE_INFO: flaresolverr 3.5.0 -> 3.5.2 https://repology.org/project/flaresolverr/versions
attrpath: flaresolverr
Checking auto update branch...
No auto update branch exists
Old version 3.5.0" not present in master derivation file with contents: {
  lib,
  stdenv,
  fetchFromGitHub,

  makeWrapper,

  chromium,
  python3,
  undetected-chromedriver,
  xvfb,

  nixosTests,
}:

let
  python = python3.withPackages (
    ps: with ps; [
      bottle
      waitress
      selenium
      func-timeout
      prometheus-client
      requests
      certifi
      websockets
      packaging
      xvfbwrapper
    ]
  );
in
stdenv.mkDerivation (finalAttrs: {
  pname = "flaresolverr";
  version = "3.5.2";

  src = fetchFromGitHub {
    owner = "FlareSolverr";
    repo = "FlareSolverr";
    rev = "v${finalAttrs.version}";
    hash = "sha256-iTFoixNcEjhTCWpfDAJoLclspiyozZnQrRfkevLzd2o=";
  };

  nativeBuildInputs = [ makeWrapper ];

  postPatch = ''
    substituteInPlace src/utils.py \
      --replace-fail \
        'CHROME_EXE_PATH = None' \
        'CHROME_EXE_PATH = "${lib.getExe chromium}"' \
      --replace-fail \
        'PATCHED_DRIVER_PATH = None' \
        'PATCHED_DRIVER_PATH = "${lib.getExe undetected-chromedriver}"'
  '';

  installPhase = ''
    mkdir -p $out/{bin,share/flaresolverr-${finalAttrs.version}}
    cp -r * $out/share/flaresolverr-${finalAttrs.version}/.

    makeWrapper ${python}/bin/python $out/bin/flaresolverr \
      --add-flags "$out/share/flaresolverr-${finalAttrs.version}/src/flaresolverr.py" \
      --prefix PATH : "${lib.makeBinPath [ xvfb ]}"
  '';

  passthru = {
    tests.smoke-test = nixosTests.flaresolverr;
  };

  meta = {
    description = "Proxy server to bypass Cloudflare protection";
    homepage = "https://github.com/FlareSolverr/FlareSolverr";
    changelog = "https://github.com/FlareSolverr/FlareSolverr/blob/${finalAttrs.src.rev}/CHANGELOG.md";
    license = lib.licenses.mit;
    mainProgram = "flaresolverr";
    maintainers = with lib.maintainers; [ diogotcorreia ];
    inherit (undetected-chromedriver.meta) platforms;
  };
})