Running nixpkgs-update (https://github.com/NixOS/infra/blob/main/non-critical-infra/modules/nixpkgs-update/README.md) with UPDATE_INFO: fribidi 1.0.17 -> 1.0.18 https://repology.org/project/fribidi/versions
attrpath: fribidi
Checking auto update branch...
No auto update branch exists
Old version 1.0.17" not present in master derivation file with contents: {
  lib,
  stdenv,
  buildPackages,
  fetchurl,
  meson,
  ninja,
  pkg-config,
  fixDarwinDylibNames,
  python3,
  testers,

  # for passthru.tests
  pango,
  libass,
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "fribidi";
  version = "1.0.18";

  __structuredAttrs = true;
  strictDeps = true;

  outputs = [
    "out"
    "dev"
    "devdoc"
  ];

  # NOTE: Only URL tarball has "Have pre-generated man pages: true", which works-around upstream usage of some rare ancient `c2man` fossil application.
  src = fetchurl {
    url =
      with finalAttrs;
      "https://github.com/fribidi/fribidi/releases/download/v${version}/fribidi-${version}.tar.xz";
    hash = "sha256-HeXoBz0DU4i3HQstRSsdofjK7qincCmXtAH+G2JQcn8=";
  };

  postPatch = ''
    patchShebangs test
  '';

  nativeBuildInputs = [
    meson
    ninja
    pkg-config
  ]
  ++ lib.optional stdenv.hostPlatform.isDarwin fixDarwinDylibNames;

  # necessary to compile helper which runs during build to generate tables
  # see gen.tab/meson.build for details
  depsBuildBuild = [ buildPackages.stdenv.cc ];

  mesonFlags = lib.mapAttrsToList lib.mesonBool {
    tests = finalAttrs.finalPackage.doCheck;
    docs = true;
    bin = true;
    deprecated = true;
  };

  doCheck = true;
  nativeCheckInputs = [ python3 ];

  passthru.tests = {
    pkg-config = testers.hasPkgConfigModules {
      package = finalAttrs.finalPackage;
    };
    inherit pango libass;
  };

  meta = {
    homepage = "https://github.com/fribidi/fribidi";
    changelog = "https://github.com/fribidi/fribidi/releases/tag/v${finalAttrs.version}";
    description = "GNU implementation of the Unicode Bidirectional Algorithm (bidi)";
    mainProgram = "fribidi";
    license = lib.licenses.lgpl21;
    platforms = lib.platforms.unix;
    pkgConfigModules = [ "fribidi" ];
    maintainers = with lib.maintainers; [ tmarkus ];
    identifiers.cpeParts = lib.meta.cpeFullVersionWithVendor "gnu" finalAttrs.version;
  };
})